Plane Stress

*TITLE 'EXFE01 - PLANE STRESS CANTILEVER EXAMBPLE'
STRUDL 'EXFE01' 'PLANE STRESS CANTILEVER EXAMPLE'
$
$***********************************************************************
$* ** PROBLEM DESCRIPTION: Sample problem for Finite Element Analysis.
$* ** This problem is similar to example 'FE-1'
$* ** in the GTSTRUDL User's Manual, Section
$* ** 2.3.9, Volume 3.
$***********************************************************************
$
$ 2 BY 8 MESH
$
UNITS KIPS INCHES
$
TYPE PLANE STRESS
$
$ USE GENERATION CAPABILITIES TO GENERATE 27 JOINTS
$ GENERATE ALONG X-AXIS, MODIFY ALONG Y-AXIS
$
GENERATE 9 JOINTS ID 1 3 X 0.0 6.0 Y -6.0 0.0
MODIFY 2 ID 1 X 0.0 Y 6.0
$
$ GENERATE 16 QUADRILATERAL ELEMENTS
$
GENERATE 8 ELEMENTS ID 1 2 FROM 1 3 TO 2 3 TO 5 3 TO 4 3
MODIFY 1 ID 1 FROM 1 TO 1 TO 1 TO 1
$
CONSTANTS
E 30000.0 ALL
POISSON 0.30 ALL
CTE 0.9E-05
$
ELEMENT PROPERTIES
1 TO 16 TYPE 'IPLQ' THICKNESS 1.0
$
$ APPLY A PARABOLICALLY VARYING END SHEAR LOAD
$ TOTAL LOAD EQUALS 40 KIPS
$
LOAD 1 'END SHEAR OF 40 KIPS'
JOINT LOADS
25 27 FORCE Y -4.0 $ EQUIVALENT JOINT LOADS
26 FORCE Y -32.0 $ EQUIVALENT JOINT LOADS
$
$ APPLY END LOAD USING EDGE FORCE CAPABILITIES
$
LOADING 2 'EDGE FORCES'
ELEMENT LOADS
$
$ USE EDGE LOAD FOR END SHEAR.
$ SINCE IPLQ IS USED, ADJUST PRESSURES SO TOTAL LOAD =40 KIPS.
$ A FINER MESH OR AN EIGHT NODE ELEMENT SHOULD BE USED TO MORE ACCURATELY
$ MODEL PARABOLIC LOAD.
$

15 EDGE FORCE EDGE 3 GLOBAL VARIABLE VY -6.6667 0.0
16 EDGE FORCE EDGE 3 GLOBAL VARIABLE VY 0.0 -6.6667
$
$ APPLY A CONSTANT TEMPERATURE CHANGE
$
LOAD 3 'TEMPERATURE LOAD'
JOINTS 1 TO 27 TEMPERATURE CHANGE 100.0
$
STATUS SUPPORT 1 TO 3
JOINT RELEASES
1 3 FORCE Y
$
STIFFNESS ANALYSIS
$
OUTPUT ORDERED
$
LIST DISPLACEMENT ALL
$
LIST REACTIONS
$
LIST SUM REACTIONS
$
LIST STRESS ALL
$
CALCULATE AVERAGE STRESSES PRINCIPAL STRESSES
$
LIST ELEMENT FORCES ELEMENTS 7 8
$
CALCULATE RESULTANT FORCES CUT 1 JOINTS 13 TO 15 ELEMENTS 7 8
FINISH